# Name: Reklamation Export
# Description: Exportiert Auftragspositionen mit Zahlungsart Reklamation im gewaehlten Zeitraum.
# FileName: reklamation_export
# UseDateFilter: true
# DateFilterInfo: a.dErstellt

SELECT
    ISNULL(ap.cName, '') AS [Artikelname],
    ISNULL(ap.cArtNr, '') AS [Artikelnummer],
    ISNULL(za.cName, '') AS [Zahlungsart],
    ISNULL(lieferant.cFirma, '') AS [Lieferant],
    CONVERT(varchar(10), a.dErstellt, 103) AS [Auftragsdatum],
    CAST(ISNULL(ap.fAnzahl, 0) AS decimal(18,2)) AS [Menge],
    ISNULL(a.cAuftragsNr, '') AS [Auftragsnummer]
FROM Verkauf.tAuftrag a
INNER JOIN Verkauf.tAuftragPosition ap
    ON ap.kAuftrag = a.kAuftrag
INNER JOIN dbo.tZahlungsart za
    ON za.kZahlungsart = a.kZahlungsart
OUTER APPLY (
    SELECT TOP 1
        l.cFirma
    FROM dbo.tliefartikel la
    INNER JOIN dbo.tlieferant l
        ON l.kLieferant = la.tLieferant_kLieferant
    WHERE la.tArtikel_kArtikel = ap.kArtikel
    ORDER BY
        l.cFirma
) lieferant
WHERE a.dErstellt >= @DateFrom
  AND a.dErstellt < @DateTo
  AND za.cName = 'Reklamation'
  AND ISNULL(ap.fAnzahl, 0) <> 0
  AND ISNULL(ap.cArtNr, '') <> ''
ORDER BY
    a.dErstellt,
    a.cAuftragsNr,
    ap.cArtNr;
